usefor-article-03 February 2000

4.1.  Syntax of News Articles

   The overall syntax of a news article is:

      article           = 1*header separator body
      header            = header-name ":" 1*SP header-content CRLF
      header-name       = 1*name-character *( "-" 1*name-character )
      name-character    = ALPHA / DIGIT
      header-content    = USENET-header-content
                     *( ";" header-parameter ) /
                other-header-content
      USENET-header-content
              = <the header-content defined in this standard
                 (or an extension of it) for a specific
                 USENET header>
      other-header-content
              = <a header-content defined (explicitly or
                 implicitly) by some other standard>
      header-parameter  = USENET-header-parameter /
                other-header-parameter
      USENET-header-parameter
              = <an other-header-parameter defined in
                 this standard for use in conjunction with
                 a specific USENET-header-content>
      other-header-parameter
              = attribute "=" value
      attribute         = USENET-token / iana-token / x-token
      value             = token / quoted-string
      USENET-token      = <A token defined in this standard for
                 use in conjunction with a specific
                 USENET-header-parameter>
      iana-token        = <A token defined in an experimental
                 or standards-track RFC and registered with
                 IANA>
      x-token           = [CFWS] <the two characters "X-" or "x-"
                 followed, with no intervening white space,
                 by any token>
      token             = [CFWS] 1*<any (US-ASCII) CHAR except SP,
                          CTLs or tspecials> [CFWS]
      tspecials         = "(" / ")" / "<" / ">" / "@" /
                "," / ";" / ":" / "\" / DQUOTE /
                "/" / "[" / "]" / "?" / "="
      separator         = CRLF
      body              = *( *998text CRLF )

   An article consists of some headers followed by a body. An empty line
   separates the two. The headers contain structured information about
   the article and its transmission. A header begins with a header-name
   identifying it, and can be continued onto subsequent lines as
   described in section 4.2.3.  The body is largely unstructured text
   significant only to the poster and the readers.

        NOTE: Terminology here follows the current custom in the news
        community, rather than the [MESSFOR] convention of referring to
        what is here called a "header" as a "header-field" or "field".

   Note that the separator line must be truly empty, not just a line
   containing white space. Further empty lines following it are part of
   the body, as are empty lines at the end of the article.

        NOTE: The syntax above defines the canonical form of a news
        article as a sequence of lines each terminated by CRLF. This
        does not prevent serving agents or transport agents from storing
        or handling the article in other formats (e.g. using a single LF
        in place of CRLF) so long as the overall effects achieved are as
        defined by this standard when operating on the canonical form.