usefor-article-05 July 2001

6.19.  Injector-Info

   The Injector-Info header SHOULD be added to each article by the
   injecting agent in order to provide information as to how that
   article entered the Netnews system and to assist in tracing its true
   origin.

      Injector-Info-content
                = path-identity
      Injector-Info-header-parameter
                = posting-host-parameter /
                  posting-account-parameter /
                  posting-sender-parameter /
                  posting-logging-parameter /
                  posting-date-parameter
                  ; for USENET-header-parameters see 4.1
      posting-host-parameter
                = [CFWS] "posting-host" [CFWS] "=" [CFWS]
                    ( host-value /
                      DQUOTE host-value DQUOTE ) [CFWS]
      host-value          = dot-atom /
                  [ dot-atom ":" ]
                    ( dotted-quad / ; see [RFC 820]
                      ipv6-numeric ) ; see [RFC 2373]
      posting-account-parameter
                =  [CFWS] "posting-account" [CFWS] "=" value
      posting-sender-parameter
                = [CFWS] "sender" [CFWS] "=" [CFWS]
                    ( sender-value /
                      DQUOTE sender-value DQUOTE ) [CFWS]
      sender-value        = ( mailbox / "verified" )
      posting-logging-parameter
                = [CFWS] "logging-data" [CFWS] "=" value
      posting-date-parameter
                = [CFWS] "posting-date" [CFWS] "=" [CFWS]
                    ( date-value /
                      DQUOTE date-value DQUOTE ) [CFWS]
      date-value          = 1*DIGIT [ ":" date-time ]

   An Injector-Info header MUST NOT be added to an article by any agent
   other than an injecting agent. Any Injector-Info header present when
   an article arrives at an injecting agent MUST be removed. In
   particular if, for some exceptional reason (8.2.2), an article gets
   injected twice, the Injector-Info header will always relate to the
   second injection.

   The path-identity MUST be the same as the path-identity prepended to
   the Path header by that same injecting agent which, following section
   5.6.2, MUST therefore be a fully qualified domain name (FQDN)
   mailable address.

   Although comments and folding of white space are permitted throughout
   the Injector-Info-content specification, it is RECOMMENDED that
   folding is not used within any header-parameter (but only before or
   after the ";" separating parameters), and that comments are only used
   following the last parameter. It is also RECOMMENDED that such
   parameters as are present are included in the order in which they
   have been defined in the syntax above.  An injecting agent SHOULD use
   a consistent form of this header for all articles emanating from the
   same or similar origins.

        NOTE: The effect of those recommendations is to facilitate the
        recognition of articles arising from certain designated origins
        (as in the so-called "killfiles" which are available in some
        reading agents). Observe that the order within the syntax has
        been chosen to place last those parameters which are most likely
        to change between successive articles posted from the same
        origin.

        NOTE:  To comply with the overall "attribute = value" syntax of
        USENET-header-parameters, any value containing an ipv6-numeric,
        a date-time, a mailbox or any CFWS MUST be quoted using
        <DQUOTE>s (the quoting is optional in other cases).

        NOTE: This header is intended to replace various currently-used
        but nowhere-documented headers such as "NNTP-Posting-Host",
        "NNTP-Posting-Date" amd "X-Trace". Any of these headers present
        when an article arrives at an injecting agent SHOULD also be
        removed as above.

--- ../usefor-article-04/Injector-Info.out          April 2001
+++ ../usefor-article-05/Injector-Info.out          July 2001